intrinsic WG2GroupRep(W::GrpFPCox,wg::GrphUnd) -> SeqEnum
{ The matrix representation of a W-graph }
  rank := Rank(W);
  V := Vertices(wg);
  E := Edges(wg);
  L:=Parent(Label(E[1]));
  graphrank := #V;
  JR:=[];
  for s in [1..rank] do
    Q := [ s in Label(u) 
      select <i,i,L!-1> else <i,i,L!1> : u in V | true where i is Index(u) ];
    for e in E do
      u := InitialVertex(e);
      v := TerminalVertex(e);
      if s in Label(u) and s notin Label(v) then
        Append(~Q, <Index(u),Index(v),L!Label(e)>);
      elif s in Label(v) and s notin Label(u) then
        Append(~Q, <Index(v),Index(u),L!Label(e)>);
      end if;
    end for;
    JR[s] := SparseMatrix( L,graphrank,graphrank,Q );
    vprint WGraph, 2 : "Matrix representing generator",s,"constructed";
  end for;
  return JR;
end intrinsic;

intrinsic WG2GroupRep(W::GrpFPCox,wg::GrphDir) -> SeqEnum
{ The matrix representation of a W-graph }
  rank := Rank(W);
  V := Vertices(wg);
  E := Edges(wg);
  L:=Parent(Label(E[1]));
  graphrank := #V;
  JR:=[];
  for s in [1..rank] do
    Q := [ s in Label(u) 
      select <i,i,L!-1> else <i,i,L!1> : u in V | true where i is Index(u) ];
    for e in E do
      u := InitialVertex(e);
      v := TerminalVertex(e);
      if s in Label(u) and s notin Label(v) then
        Append(~Q, <Index(u),Index(v),L!Label(e)>);
      end if;
    end for;
    JR[s] := SparseMatrix( L,graphrank,graphrank,Q );
    vprint WGraph, 2 : "Matrix representing generator",s,"constructed";
  end for;
  return JR;
end intrinsic;