DEMONSTRATION OF USE OF MAGMA 

given by Marston Conder at SODO, Queenstown, February 2012


........................................................................
Demonstration 1:  Coset enumeration
........................................................................

////////////////////////
// Dihedral group D_5 //
////////////////////////

G<x,y>:=Group<x,y| x^2, y^5, (x*y)^2 >;

print Order(G);


//////////////////////////
// Free group of rank 3 //
//////////////////////////

G<x,y>:=FreeGroup(3);
print Order(G);


///////////////////////////////
// Spherical triangle groups // 
///////////////////////////////

for p in [2..6] do for q in [p..6] do for r in [q..6] do 
  if (1/p)+(1/q)+(1/r) gt 1 then 
    G<x,y,z>:=Group<x,y,z| x*y*z, x^p, y^q, z^r >;
    print p,q,r,":",Order(G);
    end if;
  end for;end for;end for;


//////////////////////////////////////
// Modular group C2 * C3 = PSL(2,Z) // 
//////////////////////////////////////

G<x,y>:=Group< x,y | x^2, y^3 >; 
print AbelianQuotient(G);
print AbelianQuotientInvariants(G);

H:=sub<G| x^-1*y^-1*x*y, x*y*x^-1*y^-1 >;
print Index(G,H);

print CosetTable(G,H);
f:=CosetAction(G,H); P:=Image(f);  print P;
S:=SchreierGraph(G,H); print S; Edges(S);

print Order(G);

K:=Rewrite(G,H); print K;
print AbelianQuotientInvariants(K);


/////////////////////
// Mystery example // 
/////////////////////

G<a,b,c>:=Group<a,b,c| a^11, b^5, c^4, (a*c)^7, (a*c^-1)^7, 
 b^-1*a*b*a^-3, c^-1*b*c*b^-2, a*c^2*a*c^2*a*c^-2, 
 (a*c*a^-1*c*a*b^-1*c^-1)^2, (a*c^-1*a^-1*c^-1*a*c*b)^2, 
 a*c*a^2*c^-2*a^-1*c*a^-2*c*a^2*b*c^-1 >;

print Order(G);
n,ct:=ToddCoxeter(G,sub<G|>: CosetLimit:=2000000);
Q:=CosetImage(G,sub<G|a,b>);
print Degree(Q),Order(Q); print CompositionFactors(Q); 


///////////////////
// Trivial group //  
///////////////////

G<x>:=Group< x | x^67741 = x^84053 = 1 >; 
print Order(G);


////////////////////////////
// (2,3,6) Triangle group // 
////////////////////////////

G<x,y,z>:=Group< x,y,z | x*y*z, x^2, y^3, z^6 >; 

G:=Rewrite(G,G); print G;

H:=sub<G| x^-1*y^-1*x*y, x*y*x^-1*y^-1 >;
print Index(G,H); CosetTable(G,H);
f:=CosetAction(G,H); P:=Image(f);  print P;

print Order(G);

K:=Rewrite(G,H); print K;
print AbelianQuotientInvariants(K);


........................................................................
Demonstration 2:  Subgroups of small index in finitely-presented groups
........................................................................


////////////////////////////
// (2,3,6) Triangle group // 
////////////////////////////

G<x,y,z>:=Group< x,y,z | x*y*z, x^2, y^3, z^6 >; 

L:=LowIndexSubgroups(G,18);
print #L;

L:=LowIndexSubgroups(G,180);
print #L;

for i in [1..#L] do Q:=CosetImage(G,L[i]);
  if Index(G,L[i]) in [15,16,17,18] then print Degree(Q), Order(Q); 
  end if; end for;


/////////////////////////////////////
// Extended (2,3,7) triangle group // 
/////////////////////////////////////

G<a,b,c>:=Group< a,b,c | a^2, b^2, c^2, (a*b)^2, (b*c)^3, (a*c)^7 >; 

L:=LowIndexSubgroups(G,15);
print #L;

for i in [1..#L] do Q:=CosetImage(G,L[i]);
  print Degree(Q), Order(Q), FactoredOrder(Q); 
  end for;


//////////////////////////////////////
// Modular group C2 * C3 = PSL(2,Z) // 
//////////////////////////////////////

G<x,y>:=Group< x,y | x^2, y^3 >; 

for n in [1..10] do L:=LowIndexSubgroups(G,n);
  print "Index up to",n,"  Number of classes of subgroups =",#L;
  end for;

for n in [11..20] do L:=LowIndexSubgroups(G,n);
  print "Index up to",n,"  Number of classes of subgroups =",#L;
  end for;

........................................................................
Demonstration 3:  Normal subgroups of small index 
........................................................................

//////////////////////////////////////
// Modular group C2 * C3 = PSL(2,Z) // 
//////////////////////////////////////

G<x,y>:=Group< x,y | x^2, y^3 >; 

n:=20;
L:=LowIndexNormalSubgroups(G,n);
print "Index up to",n,"  Number of normal subgroups =",#L;

for n in [20*t : t in [1..15]] do 
  L:=LowIndexNormalSubgroups(G,n);
  print "Index up to",n,"  Number of normal subgroups =",#L;
  end for;


/////////////////////////////////////
// The Djokovic-Miller amalgam G_5 // 
/////////////////////////////////////

G5<h,p,q,r,s,a>:=Group<h,p,q,r,s,a | h^3,p^2,q^2,r^2,s^2,a^2,
(p,q),(p,r),(p,s),(q,r),(q,s),p*q*(r*s)^2, 
(h,p),h^-1*q*h*r,h^-1*r*h*p*q*r,(s*h)^2, a*p*a*q,a*r*a*s>;

n:=4800;
L:=LowIndexNormalSubgroups(G5,n); 

print "Index up to",n,"  Number of normal subgroups =",#L;
for i in [1..#L] do Q:=CosetImage(G5,L[i]`Group); 
  print i,Order(Q),FactoredOrder(Q); end for;


..........................................................................
Demonstration:  Use of low index normal subgroups to generate regular maps
..........................................................................

//////////////////////////////////////////////
// Reflexible regular maps of genus 2 to 15 // 
//////////////////////////////////////////////

maxgenus:=15;  maxo:=4*maxgenus+2;

for p in [2..maxo] do for q in [p..maxo] do if (1/p+1/q lt 1/2) then 
  ratio:=(1/2-(1/p+1/q));  lcm:=LCM(2,LCM(p,q)); 
  maxn:=(Floor(4*(maxgenus-1)/ratio) div lcm)*lcm;
  if maxn gt 0 then 
    F<a,b,c>:=Group<a,b,c| a^2,b^2,c^2, (a*c)^2,(a*b)^p,(b*c)^q >;
    L:=LowIndexNormalSubgroups(F,maxn);
    // print p,q,":",#L,"normal subgroups of index up to",maxn;
    for i in [1..#L] do f:=CosetAction(F,L[i]`Group); Q:=Image(f);
      if [Order(f(x)) : x in [a,b,c,a*c,a*b,b*c]] eq [2,2,2,2,p,q] then 
      if Index(Q,sub<Q|f(a*b),f(b*c),f(a*c)>) eq 2 then 
        n:=Order(Q); chi:=(n div (2*p)) - (n div 4) + (n div (2*q));
        g:=(2-chi) div 2; 
        print "Genus",g,"map of type",[p,q]; print FPGroup(Q);
        end if;end if;
      end for;
    end if;
  end if; end for;end for;


.............................................................................
Demonstration 4:  Use of low index normal subgroups to generate graphs
.............................................................................


/////////////////////////////////////
// Cayley graphs of order 20 to 24 // 
////////////////////////////////////

F<a,b,c>:=Group<a,b,c|a^2,b^2,c^2>;
L:=LowIndexNormalSubgroups(F,24);

graphs:=[];print "";
for t in [1..#L] do  
  rep:=L[t]`Group;  f:=CosetAction(F,rep);  Q:=Image(f); 
  if (Order(Q) in [20..24]) and (#{1,1^f(a),1^f(b),1^f(c)} eq 4) then 
    edges:={{1,1^f(u)}^g : u in [a,b,c], g in Q};
    cgs:=Graph<Degree(Q)|edges>;  okm:=false;
    for gr in graphs do if IsIsomorphic(cgs,gr) then okm:=true;break gr;end if;end for;
    if not(okm) then Append(~graphs,cgs); 
      print #graphs,": Cayley graph of order",Order(cgs), 
      "valency",Degree(Rep(VertexSet(cgs))),"girth",Girth(cgs),"diameter",Diameter(cgs);
      end if;
    end if;
  end for;

F<x,y>:=Group<x,y|x^2>;
L:=LowIndexNormalSubgroups(F,24);

graphs2:=[];print "";
for t in [1..#L] do  
  rep:=L[t]`Group;  f:=CosetAction(F,rep);  Q:=Image(f); 
  if (Order(Q) in [20..24]) and (#{1,1^f(x),1^f(y),1^f(y^-1)} eq 4) then 
    edges:={{1,1^f(u)}^g : u in [x,y,y^-1], g in Q};
    cgs:=Graph<Degree(Q)|edges>;  okm:=false;
    for gr in graphs2 do if IsIsomorphic(cgs,gr) then okm:=true;break gr;end if;end for;
    if not(okm) then Append(~graphs2,cgs); 
      print #graphs2,": Cayley graph of order",Order(cgs), 
      "valency",Degree(Rep(VertexSet(cgs))),"girth",Girth(cgs),"diameter",Diameter(cgs);
      end if;
    end if;
  end for;

for i in [1..#graphs] do for j in [1..#graphs2] do 
  if IsIsomorphic(graphs[i],graphs2[j]) then 
    print "F1 graph",i,"of order",Order(graphs[i]),
     "isomorphic to F2 graph",j,"of order",Order(graphs2[j]);
    end if;
  end for;end for;
 

////////////////////////////////
// Cayley graphs of order 128 // 
////////////////////////////////

graphs:=[];

F<x,y>:=Group<x,y|x^2>;
L:=LowIndexNormalSubgroups(F,128);
print "";

for t in [1..#L] do  
  rep:=L[t]`Group;  f:=CosetAction(F,rep);  Q:=Image(f); 
  if (Order(Q) eq 128) and (#{1,1^f(x),1^f(y),1^f(y^-1)} eq 4) then 
    edges:={{1,1^f(u)}^g : u in [x,y,y^-1], g in Q};
    cgs:=Graph<Degree(Q)|edges>;  okm:=false;
    for gr in graphs do if IsIsomorphic(cgs,gr) then okm:=true;break gr;end if;end for;
    if not(okm) then Append(~graphs,cgs); 
      print #graphs,": Cayley graph of order",Order(cgs), 
      "valency",Degree(Rep(VertexSet(cgs))),"girth",Girth(cgs),"diameter",Diameter(cgs);
      end if;
    end if;
  end for;

// Note: The analogous computation using the database of all small groups 
// takes about half an hour


//////////////////////////////////////
// 5-arc-transitive 3-valent graphs // 
//////////////////////////////////////

G5<h,p,q,r,s,a>:=Group<h,p,q,r,s,a | h^3,p^2,q^2,r^2,s^2,a^2,
(p,q),(p,r),(p,s),(q,r),(q,s),p*q*(r*s)^2, 
(h,p),h^-1*q*h*r,h^-1*r*h*p*q*r,(s*h)^2, a*p*a*q,a*r*a*s>;

L:=LowIndexNormalSubgroups(G5,4800); 

graphs:=[];print "";
for t in [1..#L] do  
  rep:=L[t]`Group;  f:=CosetAction(G5,rep);  Q:=Image(f); 
  if (Order(Q) gt 100) then 
    ff:=CosetAction(Q,sub<Q|f(h),f(p),f(r),f(s)>); QQ:=Image(ff); 
    edges:={1,1^ff(f(a))}^QQ;  atg:=Graph<Degree(QQ)|edges>;  okm:=false;
    for gr in graphs do if IsIsomorphic(atg,gr) then okm:=true;break gr;end if;end for;
    if not(okm) then Append(~graphs,atg); 
      print #graphs,": Symmetric graph of order",Order(atg), 
      "valency",Degree(Rep(VertexSet(atg))),"girth",Girth(atg),"diameter",Diameter(atg);
      end if;
    end if;
  end for;



///////////////////////////////////////////////////
// 3-arc-transitive covers of the Petersen graph // 
///////////////////////////////////////////////////

G3<h,p,q,a>:=Group<h,p,q,a | h^3,p^2,q^2,a^2,(p,q),(h,p),(q*h)^2,a*p*a*q>;

L:=LowIndexSubgroups(G3,6);  print "";
for t in [1..#L] do  
  rep:=L[t];  f:=CosetAction(G3,rep);  Q:=Image(f); 
  if (Order(Q) eq 120) then K:=rep;end if;
  end for;

print AbelianQuotientInvariants(Core(G3,K));
R:=Rewrite(G3,K); // print R;

L:=LowIndexSubgroups(R,5); 

graphs:=[];
for t in [1..#L] do  
  rep:=L[t];  f:=CosetAction(G3,rep);  Q:=Image(f); 
  if (Order(Q) in [100..15000]) then 
    ff:=CosetAction(Q,sub<Q|f(h),f(p),f(q)>); QQ:=Image(ff); 
    edges:={1,1^ff(f(a))}^QQ;  atg:=Graph<Degree(QQ)|edges>;  okm:=false;
    for gr in graphs do if IsIsomorphic(atg,gr) then okm:=true;break gr;end if;end for;
    if not(okm) then Append(~graphs,atg); 
      print "Index",Index(R,L[t]),": Symmetric graph of order",Order(atg), 
      "valency",Degree(Rep(VertexSet(atg))),"girth",Girth(atg),"diameter",Diameter(atg);
      end if;
    end if;
  end for;